Wait

Syntax

[wait ]ns

Parts

ns - number of seconds to wait. Type - double. Must be greater than zero, or:

Remarks

Wait ns seconds.

If ns is simple digits, or begins with a digit, the wait keyword can be omitted.

QM 2.2.1: The wait time precision is about 2 milliseconds (0.002 s). For example, wait 0.001 will probably wait 2 ms. In previous versions, normally it was 5 - 15 ms, although sometimes better (depends on OS and some running programs).

Note: Don't use Windows API wait functions, because then QM cannot properly end the thread on user request. It then terminates thread and displays warning in the output.

Examples

 Wait 0.5 seconds:
wait 0.5
 or:
0.5

 Wait 15 seconds; the wait time is variable wt:
int wt=15
wait wt

 Wait 2 seconds:
double F=0.5
4*F

Wait for event

Syntax

[wait ]ns event [...]

Can be used as function:

int wait(ns event [...])

Parts

ns - max number of seconds to wait. Integer (e.g. 5) or double (e.g. 0.5).

event - one of literals from the table below (WA, etc).

... - more parts. Depends on event. To understand easier, see examples at first.

Remarks

Waits for the specified event maximum ns seconds (ns<=0 means infinite). If the event does not occur within ns, macro ends (run-time error). To continue macro, use err statement.

If ns is simple digits, or begins with a digit, the wait keyword can be omitted.

The wait time precision depends on event. For key, mouse and H events, it is 0 - 10 ms. For others - from 20 to 300 ms.

Can be used as function, e.g. variable=wait(...). The return value depends on event. If not specified in the table, returns 1. If opt waitmsg was set, returns 0 if the thread receives WM_QUIT message.

On Vista, waiting for key and mouse does not work if the active window has higher integrity level (eg QM - standard user, window - administrator).

Tips

Functions mes, list, inp, modal dialogs and menus also are "wait for" functions, because they wait until are closed.

Waiting for other events can be easily implemented with rep (see example). To create new "wait for" user-defined functions, you can use WaitFor template.

Macro that contains "wait for CPU" commands, or opt waitcpu 1, sometimes may run very slowly or produce "wait timeout" errors. This is because some programs constantly or occasionally use 100% CPU, even when they are ready for input.

Waiting for image (S, -S) in large region (whole screen or window) consumes significant amount of CPU time. If during that time other application performs some processing, QM may slow down it. If processing speed is important, you can view CPU usage of qm.exe, and, if it is too high, minimize it by minimizing the search region (read more). While waiting, QM periodically searches for the image. If speed (spe) is 0, the rate is much higher.

To minimize CPU usage when waiting for a window, use window class. For example, to wait for Internet Explorer, instead of wait 0 "Internet Explorer" use wait 0 "+IEFrame" or wait 0 win("Internet Explorer" "IEFrame"). Finding window by class is much faster.

To see CPU usage, use Windows Task Manager or perfmon.exe. You can also use GetCPU function.

Examples

 Wait for window "Notepad" max. 5 seconds; on timeout error:
wait WA 5 "Notepad"
 or (WA can be omitted):
wait 5 "Notepad"
 or (wait can be omitted):
5 WA "Notepad"
 or (WA and wait can be omitted):
5 "Notepad"

 Wait for window "Notepad" max. 5 seconds; on timeout continue:
wait WA 5 "Notepad"; err

 Wait max 5 s for window "Notepad"; on timeout run macro "Open":
wait 5 WA "Notepad"
err
	mac- "Open"

 Wait until window "Notepad" is closed:
wait 0 -WC "Notepad"

 Wait until window with name "Calc" and class "SciCalc" is created:
wait 0 WC win("Calc" "SciCalc")

 Wait until control with id 1500 in window "Window" becomes enabled:
wait 0 WE id(1500 "Window")

 Wait for window "Notepad" max. 5 seconds; store window handle into variable:
int hwnd = wait(5 WA "Notepad"); err

 Wait until currently active window is deactivated (another window  becomes active); return handle of another window:
int hwnd = wait(5 -WA "")

 Wait for window "Error" or "Warning" and detect which of them is activated:
opt err 1
sel wait(5 WAI "Error[]Warning")
	case 1 out "Error"
	case 2 out "Warning"
	case 0 out "timeout"

 Wait for message "Error" or "Warning" that belongs to "APP" program:
int hwnd = wait(5 win("Error[]Warning" "#32770" "APP" 16))

 Wait for key F12:
wait 0 K F12

 Wait for any key, filter it, and display virtual-key code:
int vk = wait(0 KF)
out vk

 Run program and max. 15 seconds wait until CPU usage is less than 20%:
run "app.exe"; wait 15 P 20

 Wait for some condition that is not supported by wait:
rep() if(condition) break; else 0.1

 Wait for mouse left button down:
rep() 0.02; ifk((1)) break

 Run notepad and wait until it exits (just example of wait 0 H; use run with flag 0x400 instead):
int hProcess=run("notepad.exe")
wait 0 H hProcess; CloseHandle hProcess

 Run function "Function" in separate thread and wait until it exits:
int hThread=mac("Function")
wait 0 H hThread ;;do not close the handle!

 Create event and wait until other thread sets it:
 ______Thread1_______
int+ g_hevent
if(!g_hevent) g_hevent=CreateEvent(0 0 0 0)
wait 60 h g_hevent
bee
 ______Thread2_______
int+ g_hevent
SetEvent(g_hevent)

 Wait until one of two events is set:
int+ g_e1 g_e2
if(!g_e1) g_e1=CreateEvent(0 0 0 0)
if(!g_e2) g_e2=CreateEvent(0 0 0 0)
int i=wait(0 HM g_e1 g_e2)
out i